13.14. Example: Modal Analysis of an Acoustic-Structural Coupled Structure with Nonlinear Static Prestress Using Linear Perturbation

This example problem demonstrates the use of FLUID220 and SHELL281 to predict the resonant modes of an acoustic-structural coupled structure.

The structural shell is prestressed via a nonlinear static analysis with the large deformation first.

The mesh in the acoustic domain is morphed in terms of the deformation of the structural shell before an acoustic-structural coupled modal analysis is performed (MORPH).

Finally, the linear perturbation scheme is used to solve the resonant modes of the acoustic-structural coupled structure with updated mesh.

The acoustic domain is constructed by 0.2 x 0.2 x 0.2 m3 volume. An aluminum plate with a thickness of 0.01 m is placed at X = 0.2 m. The plate has the dimension 0.01 x 0.2 x 0.2 m3. The constraints UX = -1, UY = 0 and UZ = 0 (D) are imposed on the aluminum plate. On the X = 0 plane, the constraints UX = 0 and UZ = 0 are imposed. On the Y = 0 plane, the constraints UY = 0 and UZ = 0 are imposed.

/batch,list
/nopr
/prep7
et,1,220				! acoustic element
et,2,281				! shell element
sectype,2,shell			! define section type as shell
secdata,0.01,2,0			! shell parameters
mp,dens,1,1.2			! acoustic mass density
mp,sonc,1,343			! sound speed
mp,dens,2,2700			! aluminum mass density
mp,ex  ,2,70e9			! aluminum elastic moduli
mp,nuxy,2,.3			! aluminum minor Poisson’s rato
r,1					! real constant type 1
r,2					! real constant type 2
block,,.2,,.2,,.2		! acoustic geometry
type,1
real,1
mat,1
esize,,10
vmesh,1				! mesh acoustic domain
alls
type,2
real,2
mat,2
secnum,2
asel,s,loc,x,0.2
nsla,s,1
esurf					! create shell element
alls
! define constrains
asel,s,loc,x,.2
nsla,s,1
d,all,ux,-0.1
d,all,uy
d,all,uz
asel,s,loc,x,0
nsla,s,1
d,all,ux,0,,,,uz
asel,s,loc,y,0
nsla,s,1
d,all,uy,0,,,,uz
! define fsi interface
esel,s,type,,1
nsle,s
nsel,r,loc,x,0.2
sf,all,fsi
alls
finish
! perform non-linear static solution
/solu
antype,static
nlgeom,on
cnvtol,f,1,1e-4
nsub,1
morph,on,,,,,,,,,on		! morphing acoustic domain
rescontrol,define,all,1
solve
finish
! set up linear perturbation
/solu
antype,static,restart,,,perturb
perturb,modal,,,parkeep	! set LP to modal analysis
solve,elform
! perform modal solution
modopt,unsym,5,0.001		! set beginning frequency to 0.001 Hz
mxpand,5,,,yes
solve
finish

Release 18.2 - © ANSYS, Inc. All rights reserved.