Archive Documentation

Chapter 5: Reduced Modal Analysis Procedure

The reduced modal analysis is an archived feature requiring use of the following command:

MODOPT, Method, NMODE, FREQB, FREQE, PRMODE, Nrmkey, --, BlockSize, --, --, Scalekey .

For a reduced modal analysis, use the MODOPT command as described in the Command Reference with the following exceptions:

To perform a reduced modal analysis, follow the general procedures outlined in Modal Analysis in the Structural Analysis Guide.

During the step “Define Analysis Type and Options”, follow these instructions for a reduced modal analysis:

The following example input demonstrates a typical modal analysis procedure:

/PREP7
/TITLE, VIBRATION OF A FLUID COUPLING
C***    USING HARMONIC FLUID ELEMENTS (FLUID81) 
C***    (FLUID81 IS AN ARCHIVED ELEMENT)
ANTYPE,MODAL           ! MODE-FREQUENCY ANALYSIS
MODOPT,REDUC
ET,1,FLUID81
ET,2,COMBIN14,,,2      ! 2-D LONGITUDINAL SPRING
R,2,10                 ! HARMONIC SPRING CONSTANT
MP,EX,1,3E5
MP,DENS,1,934E-7
N,1,7
N,2,8
N,3,8,1
N,4,7,1
N,11
N,14,,1
E,1,2,3,4
TYPE,2
REAL,2
E,11,1                  ! TYPE 2 ELEMENTS WITH REAL CONSTANT 2
E,14,4
NSEL,S,LOC,X,7
CP,1,UX,ALL             ! APPROPRIATE NODAL DISPLACEMENTS COUPLED
NSEL,S,NODE,,1,4
CP,2,UZ,ALL
NSEL,ALL
M,1,UX
MODE,1
NSEL,S,LOC,X,8
D,ALL,UX                ! APPLY DISPLACEMENT CONSTRAINTS
NSEL,S,NODE,,1,4
D,ALL,UY
NSEL,S,LOC,X,0
D,ALL,ALL
NSEL,ALL
FINISH
/SOLU    
SOLVE
FINI
/POST1
*GET,F2,MODE,1,FREQ
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,1,3
LABEL(1,1) = 'f FLD81 '
LABEL(1,2) = 'Hz'
*VFILL,VALUE(1,1),DATA,1.5293
*VFILL,VALUE(1,2),DATA,F2
*VFILL,VALUE(1,3),DATA,ABS(F2/1.5293)
/COM
/OUT,example_reduced,vrt
/COM,------------------- RESULTS COMPARISON -------------
/COM,
/COM,                 |    TARGET   |    ANSYS   |    RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F11.4,'  ',F11.4,'   ',1F6.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,example_reduced,vrt

Archive Documentation


Release 18.2 - © ANSYS, Inc. All rights reserved.