2.3. Piezoelectric Analysis

Piezoelectrics is the coupling of structural and electric fields, which is a natural property of materials such as quartz and ceramics. Applying a voltage to a piezoelectric material creates a displacement, and vibrating a piezoelectric material generates a voltage. A typical application of piezoelectric analysis is a pressure transducer. Possible piezoelectric analysis types are static, modal, harmonic, and transient.

To do a piezoelectric analysis, you need to use one of these element types:

PLANE13, KEYOPT(1) = 7 - coupled-field quadrilateral solid
SOLID5, KEYOPT(1) = 0 or 3 - coupled-field brick
SOLID98, KEYOPT(1) = 0 or 3 - coupled-field tetrahedron
PLANE223, KEYOPT(1) = 1001 - coupled-field 8-node quadrilateral
SOLID226, KEYOPT(1) = 1001 - coupled-field 20-node brick
SOLID227, KEYOPT(1) = 1001 - coupled-field 10-node tetrahedron

The KEYOPT settings activate the piezoelectric degrees of freedom, displacements and VOLT. For SOLID5 and SOLID98, setting KEYOPT(1) = 3 activates the piezoelectric only option.

Large deflections, stress stiffening effects, and prestress effects are available via the NLGEOM and PSTRES commands. (See the Command Reference for more information on these commands. See the Structural Analysis Guide and Structures with Geometric Nonlinearities of the Mechanical APDL Theory Reference for more information on these capabilities.) Current-technology elements PLANE223, SOLID226 and SOLID227 also support a linear perturbation piezoelectric analysis. (See Linear Perturbation Analysis in the Structural Analysis Guide for information about the procedure.)

For PLANE13, large deflection and stress stiffening capabilities are available for KEYOPT(1) = 7. For SOLID5 and SOLID98, large deflection and stress stiffening capabilities are available for KEYOPT(1) = 3. In addition, small deflection stress stiffening capabilities are available for KEYOPT(1) = 0.

For a large-deflection piezoelectric analysis, you must use nonlinear solution commands to specify your settings. For general information on these commands, refer to Set Solution Controls in the Structural Analysis Guide.

The following related topics are available:

2.3.1. Hints and Recommendations for Piezoelectric Analysis

The analysis may be static, modal, harmonic, transient, or prestressed modal, harmonic, or transient. Some important points to remember are:

  • For modal analysis, Block Lanczos is the recommended solver. The Supernode and Subspace solvers are also allowed. PCG Lanczos is not supported unless using Lev_Diff = 5 on the PCGOPT command.

  • For static, full harmonic, or full transient analysis, select the sparse matrix (SPARSE) solver or the Jacobi Conjugate Gradient (JCG) solver. The sparse solver is the default for static and full transient analyses. Depending on the chosen system of units or material property values, the assembled matrix may become ill-conditioned. When solving ill-conditioned matrices, the JCG iterative solver may converge to the wrong solution. The assembled matrix typically becomes ill-conditioned when the ratios of the magnitudes of the structural DOF and electrical DOF become very large (more than 1e15).

  • For transient analyses, specify ALPHA = 0.25, DELTA = 0.5, and THETA = 0.5 on the TINTP command (Main Menu> Preprocessor> Loads> Time/Frequenc>Time Integration).

  • A linear perturbation piezoelectric analysis is available only with PLANE223, SOLID226, and SOLID227 elements.

  • For PLANE13, SOLID5, and SOLID98, the force label for the VOLT DOF is AMPS. For PLANE223, SOLID226, and SOLID227, the force label for the VOLT degree of freedom is CHRG. Use these labels in F, CNVTOL, RFORCE, etc.

  • To do a piezoelectric-circuit analysis, use CIRCU94.

  • The capability to model dielectric losses using the dielectric loss tangent property (input on MP,LSST) is available only for PLANE223, SOLID226, and SOLID227.

  • The Coriolis effect capability is available only for PLANE223, SOLID226, and SOLID227. For information on how to include this effect, see Rotating Structure Analysis in the Advanced Analysis Guide. For a sample analyses, see Example: Piezoelectric Analysis with Coriolis Effect.

  • If a model has at least one piezoelectric element, then all the coupled-field elements with structural and VOLT degrees of freedom must be of piezoelectric type. If the piezoelectric effect is not desired in these elements, simply define very small piezoelectric coefficients on TB.

  • Mode-superposition transient and harmonic analyses are available. For volt excitation, use the enforced motion procedure (for an example, see Example: Mode-Superposition Piezoelectric Analysis). Because mode-superposition analysis assumes proportional damping, electrical sensitivity (MP,RSVX, RSVY and RSVZ) and electric loss tangent (MP,LSST) are not supported. If you are interested in results such as electric fields (Item = EF on PRNSOL, PLNSOL, PRESOL, or PLESOL) or charges (Item = CHRG on PRESOL or PLESOL), request an expansion which is not based on modal elements results by specifying MSUPkey = NO on the MXPAND command.

2.3.2. Material Properties for Piezoelectric Analysis

A piezoelectric model requires permittivity (or dielectric constants), the piezoelectric matrix, and the elastic coefficient matrix to be specified as material properties. See the following topics for details:

2.3.2.1. Permittivity Matrix (Dielectric Constants)

For SOLID5, PLANE13, or SOLID98 you specify relative permittivity values as PERX, PERY, and PERZ on the MP command (Main Menu> Preprocessor> Material Props> Material Models> Electromagnetics> Relative Permittivity> Orthotropic). (Refer to the EMUNIT command for information on free-space permittivity.) The permittivity values represent the diagonal components ε11, ε22, and ε33 respectively of the permittivity matrix [εS]. (The superscript "S" indicates that the constants are evaluated at constant strain.) That is, the permittivity input on the MP command will always be interpreted as permittivity at constant strain [εS].


Note:  If you enter permittivity values less than 1 for SOLID5, PLANE13, or SOLID98, the program interprets the values as absolute permittivity.


For PLANE223, SOLID226, and SOLID227, you can specify permittivity either as PERX, PERY, PERZ on the MP command or by specifying the terms of the anisotropic permittivity matrix using the TB,DPER and TBDATA commands. If you select to use the MP command to specify permittivity, the permittivity input will be interpreted as permittivity at constant strain. If you select to use the TB,DPER command (Main Menu> Preprocessor> Material Props> Material Models> Electromagnetics> Relative Permittivity> Anisotropic), you can specify the permittivity matrix at constant strain [εS] (TBOPT = 0) or at constant stress [εT] (TBOPT = 1). The latter input will be internally converted to permittivity at constant strain [εS] using the piezoelectric strain and stress matrices. The values input on either MP,PERX or TB,DPER will always be interpreted as relative permittivity.

2.3.2.2. Piezoelectric Matrix

You can define the piezoelectric matrix in [e] form (piezoelectric stress matrix) or in [d] form (piezoelectric strain matrix). The [e] matrix is typically associated with the input of the anisotropic elasticity in the form of the stiffness matrix [c], while the [d] matrix is associated with the compliance matrix [s].


Note:  The program converts a piezoelectric strain matrix [d] matrix to a piezoelectric stress matrix [e] using the elastic matrix at the first defined temperature. To specify the elastic matrix required for this conversion, use the TB,ANEL command (not the MP command).


This 6 x 3 matrix (4 x 2 for 2-D models) relates the electric field to stress ([e] matrix) or to strain ([d] matrix). Both the [e] and the [d] matrices use the data table input described below:

The TB,PIEZ and TBDATA commands are used to define the piezoelectric matrix; see your Command Reference for the order of input of these constants.

To define the piezoelectric matrix via the GUI, use the following:

Main Menu> Preprocessor> Material Props> Material Models> Piezoelectrics> Piezoelectric matrix

For most published piezoelectric materials, the order used for the piezoelectric matrix is x, y, z, yz, xz, xy, based on IEEE standards (see ANSI/IEEE Standard 176–1987), while the input order is x, y, z, xy, yz, xz as shown above. This means that you need to transform the matrix to the input order by switching row data for the shear terms as shown below:

  • IEEE constants [e61, e62, e63] would be input as the xy row

  • IEEE constants [e41, e42, e43] would be input as the yz row

  • IEEE constants [e51, e52, e53] would be input as the xz row

2.3.2.3. Elastic Coefficient Matrix

This 6 x 6 symmetric matrix (4 x 4 for 2-D models) specifies the stiffness ([c] matrix) or compliance ([s] matrix) coefficients.


Note:  This section follows the IEEE standard notation for the elastic coefficient matrix [c]. The matrix is also referred to as [D].


The elastic coefficient matrix uses the following data table input:

Use the TB,ANEL (Main Menu> Preprocessor> Material Props> Material Models> Structural> Linear> Elastic> Anisotropic) and TBDATA commands to define the coefficient matrix [c] (or [s], depending on the TBOPT settings); see the Command Reference for the order of input of these constants. As explained for the piezoelectric matrix, most published piezoelectric materials use a different order for the [c] matrix. You need to transform the IEEE matrix to the input order by switching row and column data for the shear terms as shown below:

  • IEEE terms [c61, c62, c63, c66] would be input as the xy row

  • IEEE terms [c41, c42, c43, c46, c44] would be input as the yz row

  • IEEE terms [c51, c52, c53, c56, c54, c55] would be input as the xz row

An alternative to the [c] matrix is to specify Young's modulus (MP,EX command) and Poisson's ratio (MP,NUXY command) and/or shear modulus (MP,GXY command). (See the Command Reference for more information on the MP command). To specify any of these via the GUI, use the following:

Main Menu> Preprocessor> Material Props> Material Models> Structural> Linear> Elastic> Orthotropic

For micro-electromechanical systems (MEMS), it is best to set up problems in µMKSV or µMSVfA units (see Table 1.9: Piezoelectric Conversion Factors for MKS to μMKSV and Table 1.16: Piezoelectric Conversion Factors for MKS to μMKSVfA).

2.3.3. Example: Piezoelectric Analysis

This example problem considers a piezoelectric bimorph beam in actuating and sensing modes.

2.3.3.1. Problem Description

A piezoelectric bimorph beam is composed of two piezoelectric layers joined together with opposite polarities. Piezoelectric bimorphs are widely used for actuation and sensing. In the actuation mode, on the application of an electric field across the beam thickness, one layer contracts while the other expands. This results in the bending of the entire structure and tip deflection. In the sensing mode, the bimorph is used to measure an external load by monitoring the piezoelectrically induced electrode voltages.

As shown in Figure 2.6: Piezoelectric Bimorph Beam, this is a 2-D analysis of a bimorph mounted as a cantilever. The top surface has ten identical electrode patches and the bottom surface is grounded.

In the actuator simulation, perform a linear static analysis. For an applied voltage of 100 Volts along the top surface, determine the beam tip deflection. In the sensor simulation, perform a large deflection static analysis. For an applied beam tip deflection of 10 mm, determine the electrode voltages (V1, V2, ... V10) along the beam.

Figure 2.6:  Piezoelectric Bimorph Beam

Piezoelectric Bimorph Beam

2.3.3.2. Problem Specifications

The bimorph material is Polyvinylidene Fluoride (PVDF) with the following properties:

Young's modulus (E1) = 2.0e9 N/m2
Poisson's ratio (ν12) = 0.29
Shear modulus (G12) = 0.775e9 N/m2
Piezoelectric strain coefficients (d31) = 2.2e-11 C/N, (d32) = 0.3e-11 C/N, and (d33) = -3.0e-11 C/N
Relative permittivity at constant stress (ε33)T = 12

The geometric properties are:

Beam length (L) = 100 mm
Layer thickness (H) = 0.5 mm

Loadings for this problem are:

Electrode voltage for the actuator mode (V) = 100 Volts
Beam tip deflection for the sensor mode (Uy) = 10 mm

2.3.3.3. Results

Actuator Mode

A deflection of -32.9 µm is calculated for 100 Volts.

This deflection is close to the theoretical solution determined by the following formula (J.G. Smits, S.I. Dalke, and T.K. Cooney, “The constituent equations of piezoelectric bimorphs,” Sensors and Actuators A, 28, pp. 41–61, 1991):

Uy = -3(d31)(V)(L)2/8(H)2

Substituting the problem values gives a theoretical deflection of -33.0 µm.

Sensor Mode

Electrode voltage results for a 10 millimeter beam tip deflection are shown in Table 2.10: Electrode 1-5 Voltages and Table 2.11: Electrode 6-10 Voltages. They are in good agreement with those reported by W.-S. Hwang and H.C. Park (“Finite Element Modeling of Piezoelectric Sensors and Actuators,” American Institute of Aeronautics and Astronautics, Vol. 31, No.5, pp. 930-937, 1993).

Table 2.10:  Electrode 1-5 Voltages

Electrode 12345
Volts 295.2266.7235.3203.8172.3

Table 2.11:  Electrode 6-10 Voltages

Electrode 678910
Volts 140.9109.578.247.118.2

2.3.3.4. Command Listing

The command listing below demonstrates the problem input. Text prefaced by an exclamation point (!) is a comment. An alternative element type and material input.are included in the comment lines.

/batch,list
/title, Static Analysis of a Piezoelectric Bimorph Beam
/nopr
/com,
/PREP7
!
!  Define problem parameters
!
!   - Geometry
!
L=100e-3                        ! Length, m
H=0.5e-3                        ! One-layer thickness, m
!
!   - Loading
!
V=100                           ! Electrode voltage, Volt
Uy=10.e-3                       ! Tip displacement, m
!
!   - Material properties for PVDF 
!
E1=2.0e9                        ! Young's modulus, N/m^2 
NU12=0.29                       ! Poisson's ratio
G12=0.775e9                     ! Shear modulus, N/m^2 
d31=2.2e-11                     ! Piezoelectric strain coefficients, C/N
d32=0.3e-11
d33=-3.0e-11
ept33=12                        ! Relative permittivity at constant stress 
!
! Finite element model of the piezoelectric bimorph beam
!
local,11                        ! Coord. system for lower layer: polar axis +Y 
local,12,,,,,180                ! Coord. system for upper layer: polar axis -Y
csys,11                         ! Activate coord. system 11
rect,0,L,-H,0                   ! Create area for lower layer
rect,0,L, 0,H                   ! Create area for upper layer
aglue,all                       ! Glue layers
esize,H                         ! Specify the element length
!
et,1,PLANE223,1001,,0           ! 2-D piezoelectric element, plane stress

tb,ANEL,1,,,1                  ! Elastic compliance matrix
tbda,1,1/E1,-NU12/E1,-NU12/E1
tbda,7,1/E1,-NU12/E1
tbda,12,1/E1
tbda,16,1/G12

tb,PIEZ,1,,,1                   ! Piezoelectric strain matrix
tbda,2,d31
tbda,5,d33
tbda,8,d32

tb,DPER,1,,,1                   ! Permittivity at constant stress
tbdata,1,ept33,ept33

tblist,all                      ! List input and converted material matrices

! -------------------------------------------------------------------------
!          Alternative element type and material input
!
!et,1,PLANE13,7,,2               ! 2-D piezoelectric element, plane stress
!
!mp,EX,1,E1                      ! Elastic properties
!mp,NUXY,1,NU12
!mp,GXY,1,G12
!
!tb,PIEZ,1                       ! Piezoelectric stress matrix
!tbda,2,0.2876e-1
!tbda,5,-0.5186e-1
!tbda,8,-0.7014e-3
!
!mp,PERX,1,11.75                 ! Permittivity at constant strain
! -------------------------------------------------------------------------
type,1 $ esys,11
amesh,1                         ! Generate mesh within the lower layer
type,1 $ esys,12             
amesh,3                         ! Generate mesh within the upper layer
!
nsel,s,loc,x,L                  
*get,ntip,node,0,num,min        ! Get master node at beam tip
!
nelec = 10                      ! Number of electrodes on top surface
*dim,ntop,array,nelec
l1 = 0                          ! Initialize electrode locations
l2 = L/nelec           
*do,i,1,nelec                   ! Define electrodes on top surface     
nsel,s,loc,y,H                
nsel,r,loc,x,l1,l2
cp,i,volt,all
*get,ntop(i),node,0,num,min     ! Get master node on top electrode
l1 = l2 + H/10                  ! Update electrode location
l2 = l2 + L/nelec
*enddo
nsel,s,loc,y,-H                 ! Define bottom electrode
d,all,volt,0                    ! Ground bottom electrode
nsel,s,loc,x,0                  ! Clamp left end of bimorph
d,all,ux,0,,,,uy
nsel,all
fini
/SOLU                           ! Actuator simulation
antype,static                   ! Static analysis
*do,i,1,nelec
d,ntop(i),volt,V                ! Apply voltages to top electrodes
*enddo
solve
Uy_an = -3*d31*V*L**2/(8*H**2)  ! Theoretical solution
/com,
/com, Actuator mode results:
/com, - Calculated tip displacement Uy = %uy(ntip)% (m)
/com, - Theoretical solution        Uy = %Uy_an% (m)
fini
/SOLU                           ! Sensor simulation
antype,static,new
*do,i,1,nelec
ddele,ntop(i),volt              ! Delete applied voltages
*enddo
d,ntip,uy,Uy                    ! Apply displacement to beam tip
nlgeom,on                       ! Activate large deflections
nsubs,2                         ! Set number of substeps
cnvtol,F,1.e-3,1.e-3            ! Set convergence for force
cnvtol,CHRG,1.e-8,1.e-3         ! Set convergence for charge
!cnvtol,AMPS,1.e-8,1.e-3         ! Use AMPS label with PLANE13
solve
fini
/POST1
/com,
/com, Sensor mode results:
*do,i,1,nelec
/com, - Electrode %i%  Voltage = %volt(ntop(i))% (Volt)
*enddo
/com,
/view,,1,,1                     ! Set viewing directions 
/dscale,1,1                     ! Set scaling options
pldisp,1                        ! Display deflected and undeflected shapes
path,position,2,,100            ! Define path name and parameters
ppath,1,,0,H                    ! Define path along bimorph length
ppath,2,,L,H
pdef,Volt,volt,,noav            ! Interpolate voltage onto the path
pdef,Uy,u,y                     ! Interpolate displacement onto the path
/axlab,x, Position (m)
/axlab,y, Electrode Voltage (Volt)
plpath,Volt                     ! Display electrode voltage along the path 
/axlab,y, Beam Deflection (m)
plpath,Uy                       ! Display beam deflection along the path
pasave                          ! Save path in a file
fini

2.3.4. Example: Piezoelectric Analysis with Coriolis Effect

This example demonstrates a piezoelectric analysis with Coriolis effect in a rotating reference frame.

2.3.4.1. Problem Description

A quartz tuning fork for an angular velocity sensor consists of two tines connected to a base that is fixed at the bottom. SOLID226 elements model the tuning fork as shown in the following figure.

Figure 2.7:  Finite Element Model of Quartz Tuning Fork

Finite Element Model of Quartz Tuning Fork

The tuning fork is excited into an in-plane vibration by an applied alternating voltage. When the tuning fork is rotated about the axis parallel to the tines (Y-axis) with an angular velocity Ω, the Coriolis effect produces a torque proportional to Ω. Converted to an electric output signal, the amplitude of the out-of-plane vibration can be used to sense the rotational velocity in angular velocity sensors.

Figure 2.8:  Voltage Load for In-Plane Vibration

Voltage Load for In-Plane Vibration

A QR-damped modal analysis (MODOPT,QRDAMP) of the rotating tuning fork is performed to determine the shift in the eigenfrequencies due to Coriolis and spin-softening effects. The Coriolis effect is activated in a rotating reference frame by the CORIOLIS,ON,,,OFF command. Angular velocity is specified by the OMEGA command.

A harmonic analysis is also performed to demonstrate the effect of Coriolis force in the vicinity of the 4th resonance.

2.3.4.2. Problem Specifications

Geometric and material properties are input in the μMKSV system of units. For more information on units, see System of Units.

The tuning fork dimensions are:

Thickness (T) = 350 μm
Tine width (W_t) = 450 μm
Base width (W) = 1250 μm
Tine length (L_t) = 3200 μm
Total length (L) = 4800 μm

Material property inputs for quartz are: elastic coefficients, piezoelectric coefficients, dielectric constants, and density (Bechmann, R., “Elastic and Piezoelectric Constants of Alpha-Quartz,” Physical Review, v.110, pp. 1060-1061 (1958)).

The operating parameters are:

Angular velocity (Ω) = 1e4 rad/s (Ω is typically around 1 rad/s for gyroscopes. It is greatly exaggerated here to show the out-of-plane motion in the animation.)
Operating frequency (f) = 32768 Hz (This frequency corresponds to a quartz clock. Gyroscopes can operate at a different frequency.)

2.3.4.3. Results

Eigenfrequencies are shown in the following table. Spin-softening effects are included by default in dynamic analyses when the CORIOLIS command is set to ON.

Table 2.12:  Tuning Fork Eigenfrequencies (Hz)

Mode No Inertia Effects Coriolis Effect and Spin-Softening
1st1509514904
2nd 2405223765
3rd 3012930303
4th 3273633020

To expand the corresponding complex mode shapes, you set the Cpxmod argument on the MODOPT command to ON and use the MXPAND command.

The in-plane and out-of-plane vibrations in the vicinity of the 4th resonance are shown in the following animation. View the animation online if you are reading the PDF version of the help.

Figure 2.9:  In-Plane and Out-of-Plane Vibrations

In-Plane and Out-of-Plane Vibrations

2.3.4.4. Command Listing

The command listing below demonstrates the problem input. Text prefaced by an exclamation point (!) is a comment.

/title, Coriolis Effect in a Vibrating Quartz Tuning Fork
/com  uMKS system of units
/nopr

pi  = 4*atan(1)
/VIEW,1,1,1,1 
/TRIAD,lbot

/PREP7
! == Material parameters
! -- Elastic coefficients, MPa
c11      = 86.74e3    
c12      = 6.99e3    
c13      = 11.91e3    
c14      = 17.91e3    
c33      = 107.2e3
c44      = 57.94e3
tb,ANEL,1
tbdata, 1,  c11, c12, c13,    0, c14,    0
tbdata, 7,       c11, c13,    0,-c14,    0
tbdata,12,            c33,    0,   0,    0
tbdata,16,          (c11-c12)/2,   0,  c14   
tbdata,19,                       c44,    0   
tbdata,21,                             c44

! -- Piezoelectric coefficients, pC/um2
e11 = 0.171   
e14 =-0.0406   
tb,PIEZ,1
tbdata, 1,  e11,    0,   0
tbdata, 4, -e11,    0,   0
tbdata, 7,    0,    0,   0
tbdata,10,    0, -e11,   0     
tbdata,13,  e14,    0,   0     
tbdata,16,    0, -e14,   0

! -- Dielectric constants 
emunit,EPZRO,8.854e-6             ! pF/um
mp,PERx,1, 4.43                  
mp,PERy,1, 4.43
mp,PERz,1, 4.63

! -- Density, kg/um3
mp,DENS,1,2649e-18        

! == Dimensions, um

thick    =  350                   ! thickness of wafer
leng_TF  = 4800                   ! length of tuning fork
leng_tin = 3200                   ! length of tines
dist_t   =  350                   ! distance between tines
width_t  =  450                   ! width of tines
x_t_in   = dist_t/2               ! distance to outer part of tines
x_t_out  = dist_t/2 + width_t     ! distance to inner part of tines

! == FE Model

et,1,SOLID226,1001                ! piezoelectric 20-node brick

! -- Keypoints
k, 1, 0,       0                , -thick/2
k, 2, 0,       leng_TF-leng_tin , -thick/2
k, 3, x_t_in,  0                , -thick/2
k, 4, x_t_in,  leng_TF-leng_tin , -thick/2
k, 5, x_t_in,  leng_TF          , -thick/2
k, 6, x_t_out, 0                , -thick/2
k, 7, x_t_out, leng_TF-leng_tin , -thick/2
k, 8, x_t_out, leng_TF          , -thick/2

! -- Areas
a,1,3,4,2   
a,3,6,7,4
a,4,7,8,5

! -- Lines
lesize, 5,,,  4,                  ! X, tines
*repeat,3,2           
lesize, 1,,,  2,                  ! X, between tines
lesize, 3,,,  2,    
lesize, 8,,, 14,  3               ! Y, tines
lesize,10,,, 14, 1/3 
lesize, 2,,, 8, -2                ! Y, base
*repeat,3,2             
*get,n_lin,LINE,,count            ! number of lines
lgen,2,1, n_lin, 1,,, thick,20    ! generate top layer lines 
l,1,21, 4,                        ! thickness direction
*repeat,8,1,1                 

lsymm,X,all,,,100                 ! generate left half of tuning fork

! -- Volumes
v,  1,  3,  4,  2,  21, 23, 24, 22
v,  3,  6,  7,  4,  23, 26, 27, 24 
v,  4,  7,  8,  5,  24, 27, 28, 25
v,101,103,104,102, 121,123,124,122
v,103,106,107,104, 123,126,127,124 
v,104,107,108,105, 124,127,128,125
vplot
nummrg,kp

! -- Mesh
type,1
vmesh,all

! == Define electrodes 
delta=20                         ! separation between electrodes and edge

! -- Loaded electrode
nsel,s,loc,x, x_t_in+delta, x_t_out-delta     ! top/bottom right tine
nsel,u,loc,z, -thick/2+1, thick/2-1
nsel,a,loc,x, -x_t_out-1, -x_t_out+1          ! sides of left tine
nsel,a,loc,x, -x_t_in-1,  -x_t_in+1
nsel,r,loc,y, leng_TF-leng_tin-1, leng_TF-leng_tin*0.45  ! select tine-nodes
cp,1,volt,all
n_load=ndnext(0)                 ! get master node on loaded electrode

! -- Ground electrode
nsel,s,loc,x, -x_t_out+delta, -x_t_in-delta   ! top/bottom left tine
nsel,u,loc,z, -thick/2+1, thick/2-1
nsel,a,loc,x, x_t_out-1, x_t_out+1            ! sides of right tine
nsel,a,loc,x, x_t_in-1,  x_t_in+1
nsel,r,loc,y, leng_TF-leng_tin-1, leng_TF-leng_tin*0.45  ! select tine-nodes
cp,2,volt,all
n_ground=ndnext(0)               ! get master node on ground electrode
nsel,all

! == Solution
/SOLU
! -- Structural constraints
nsel,s,loc,y
d,all,ux,0,,,,uy,uz                                                                       
nsel,all        

! -- Ground electrode
d,n_ground,volt,0                ! ground 
! -- Loaded electrode
d,n_load,volt,1                  ! apply 1 Volt
                                                                    
! -- Add Coriolis effect 
coriolis,on,,,off                ! Coriolis effect in a rotating reference frame
omega,,1.e4                      ! rotational velocity about the Y axis, rad/s                                                               
fini

! == Modal analysis
/SOLU
antype,modal
modopt,QRDAMP,4                  ! use damped eigensolver
solve                   
fini

! ==Harmonic analysis
/SOLU
antype,harm
dmprat,0.02                      ! specify structural damping ratio of 2%
harfrq,,32768
outres,all,all
solve
fini

/POST1
set,1,1
/dscale,1,6
plns,uz
anharm                           ! animate complex displacements
fini

2.3.5. Example: Mode-Superposition Piezoelectric Analysis

This example problems considers a simplified model of a piezoelectric fan to demonstrate the mode-superposition harmonic procedure.

2.3.5.1. Problem Description

A piezoelectric bimorph beam is considered, as in Example: Piezoelectric Analysis. For a specific description of the beam, see Problem Description. In this example, the beam is a cantilever and only one fourth of its length has piezoelectric characteristics. The rest is a purely structural flexible beam which amplifies the piezoelectric motion.

As voltage is applied along the upper layer of the piezoelectric part, the beam oscillates and generates airflow.

A mode-superposition harmonic analysis is performed to obtain the amplitude of vibration as a function of the alternating current frequency.

2.3.5.2. Problem Specifications

The biomorph material is Polyvinylidene Fluoride (PVDF) with the following properties:

Young’s modulus (E1) = 2.0 x 109 N/m2
Poisson’s ratio (v12) = 0.29
Shear modulus (G12) = 0.775 x 109 N/m2
Piezoelectric strain coefficients (d31) = 2.2 x 10-11 C/N, (d32) = 0.3 x 10-11 C/N, and (d33) = -3.0 x 10-11 C/N
Relative permittivity at constant stress (ε33)T = 12

The geometric properties are:

Beam length (L) = 100 mm
Layer thickness (H) = 0.5 mm

The loading for this problem is:

Electrode voltage = 100 Volts

2.3.5.3. Results

The volt solution and the animation of the vibration in the vicinity of the 1st resonance frequency are shown in the following figures. View the animation online if you are using the PDF version of this document.

Figure 2.10:  Volt solution at 27.6 Hz

Volt solution at 27.6 Hz

Figure 2.11:  Animation of the Solution at 27.6 Hz

Animation of the Solution at 27.6 Hz

The evolution of the tip deflection with respect to the frequency is shown below.

Figure 2.12:  Tip Deflection

Tip Deflection

2.3.5.4. Command Listing

The command text below demonstrates the problem input. All text prefaced with an exclamation point (!) is a comment.

/title, MSUP Harmonic Analysis of a Piezoelectric Fan
/PREP7
!
!   - Geometry
!
L=100e-3                        ! Length, m
H=0.5e-3                        ! One-layer thickness, m
!
!   - Loading
!
V=100                           ! Electrode voltage, Volt
!
!   - Material properties for PVDF 
!
E1=2.0e9                        ! Young's modulus, N/m^2 
NU12=0.29                       ! Poisson's ratio
G12=0.775e9                     ! Shear modulus, N/m^2 
d31=2.2e-11                     ! Piezoelectric strain coefficients, C/N
d32=0.3e-11
d33=-3.0e-11
ept33=12                        ! Relative permittivity at constant stress 

!
! Finite element model of the piezoelectric bimorph beam
!
local,11                        ! Coord. system for lower layer: polar axis +Y 
local,12,,,,,180                ! Coord. system for upper layer: polar axis -Y
csys,11                         ! Activate coord. system 11
rect,0,L,-H,0                   ! Create area for lower layer
rect,0,L, 0,H                   ! Create area for upper layer
aglue,all                       ! Glue layers
esize,H                         ! Specify the element length

et,1,PLANE223,1001,,0           ! 2-D piezoelectric element, plane stress

tb,ANEL,1,,,1                  ! Elastic compliance matrix
tbda,1,1/E1,-NU12/E1,-NU12/E1
tbda,7,1/E1,-NU12/E1
tbda,12,1/E1
tbda,16,1/G12

tb,PIEZ,1,,,1                   ! Piezoelectric strain matrix
tbda,2,d31
tbda,5,d33
tbda,8,d32

tb,DPER,1,,,1                   ! Permittivity at constant stress
tbdata,1,ept33,ept33

mp,dens,1,1000

type,1 $ esys,11
amesh,1                         ! Generate mesh within the lower layer
type,1 $ esys,12             
amesh,3                         ! Generate mesh within the upper layer

!
! Finite element of the "fan" from L/4 to L
!
et,2,182
mp,ex,2,.1e12
mp,dens,2,1000
mp,prxy,2,0.3
csys,0
nsel,s,loc,x,L/4,L
esln
emod,all,type,2
emod,all,mat,2
allsel

!
! Boundary conditions
!
nsel,s,loc,y,-H
nsel,r,loc,x,0,L/4
d,all,volt,0
allsel

nsel,s,loc,x,0
d,all,ux,0
d,all,uy,0
nsel,all
finish

!
! Modal Analysis
!
/solu
antype,modal
modopt,lanb,12
mxpand,12

modcont,,on            ! Activate the enforced motion calculation
nsel,s,loc,y,H
nsel,r,loc,x,0,L/4
d,all,volt,1              ! Create the enforced motion load vector #1
allsel

solve
finish

!
! MSUP Harmonic Analysis
!
/solu
antype,harm
hropt,msup
harfrq,10,450
nsub,500
kbc,1
dmprat,0.02
dval,1,u,100.0         ! Use the enforced motion load vector #1 - scaling = 100.0
solve
finish

!
! Expansion Pass
!
/solu
expass,on
numexp,all
solve
finish

!
! Postprocessing
!
/post1
set,1,20
plnsol,volt
plnsol,u,y
anharm
finish
/post26
nsol,3,node(L,0,0),u,y,uytip
plcplx,0
/grop,logy,1
plvar,3
finish

Release 18.2 - © ANSYS, Inc. All rights reserved.