The micro mirror problem demonstrates the reduced order modeling procedure of an electrostatically actuated MEMS with multiple electrodes. The micro mirror cell is part of a complex mirror array used for light deflection applications. The entire mirror array consists of six separate mirror strips driven synchronously in order to achieve high-speed light deflection. Each strip is attached to the wafer surface by two intermediate anchor posts. Due to the geometrical symmetry, the mirror strips can be divided into three parts whereby just one section is necessary for finite element analyses.
The electrostatic domain consists of three conductors, where the nodes of the mirror itself are defined by node component COND1, and the fixed ground conductors are node components COND2 and COND3. The fixed conductors are on top of the ground plate shown in Figure 8.10: Schematic View of a Micro Mirror Array and a Single Mirror Cell and Figure 8.11: Parameter Set for Geometrical Dimensions of the Mirror Cell.
The model uses hexahedral solid elements (SOLID185) for the structural domain and tetrahedral elements (SOLID122) for the electrostatic domain.
Model Input File:
/TITLE, Silicon micro mirror cell
/filname,mirror
/PREP7
! uMKSV units
fe_la=200 ! Spring length
fe_br=10 ! Spring width
fe_di=15 ! Spring thickness
sp_la=1000 ! Mirror length
sp_br=250 ! Mirror width
mi_la=520 ! Length center part
mi_br=35 ! Width center part
po_la=80 ! Length of anchor post
po_br=80 ! Width of anchor post
fr_br=30 ! Fringing field distance
d_ele=20 ! Electrode gap
ET,1,SOLID185,,3 ! Structural domain
ET,2,SOLID122 ! Electrostatic domain
EMUNIT,EPZRO,8.85e-6 ! Free space permittivity
MP,PERX,2,1 ! Relative permittivity of air
del1=(mi_br-fe_br)/2
K,1
K,2,,fe_br/2
K,3,,mi_br/2
K,4,,po_br/2+(mi_br-fe_br)/2
K,5,,sp_br/2
K,6,,sp_br/2+fr_br
KGEN,2,1,6,1,mi_la/2
KGEN,2,1,6,1,mi_la/2+fe_la-(mi_br-fe_br)/2
KGEN,2,1,6,1,sp_la/2
K,21,sp_la/2,po_br/2
K,13,sp_la/2-po_la/2
K,14,sp_la/2-po_la/2,fe_br/2
K,25,sp_la/2-po_la/2,po_br/2
A,3,9,10,4
A,9,15,16,10
A,4,10,11,5
A,10,16,17,11
A,16,22,23,17
AGEN,2,ALL,,,,,-d_ele
ASEL,S,LOC,Z,-d_ele
AADD,ALL
ASEL,ALL
A,1,7,8,2
A,2,8,9,3
A,7,13,14,8
A,13,19,20,14
A,14,20,21,25
ASEL,S,LOC,Z,0
VEXT,ALL,,,,,fe_di
ASEL,ALL
ASEL,S,AREA,,9,10
VEXT,ALL,,,,,-d_ele
ASEL,ALL
VATT,1,,1
BLOCK,0,sp_la/2,o,sp_br/2+fr_br,-d_ele,fe_di
VDELE,13
AOVLAP,ALL
ASEL,S,LOC,Z,fe_di
ASEL,A,LOC,Z,-d_ele
ASEL,A,LOC,X,0
ASEL,A,LOC,X,sp_la/2
ASEL,A,LOC,Y,0
ASEL,A,LOC,Y,sp_br/2+fr_br
VA,ALL
VSBV,13,ALL,,,KEEP
VSEL,S,VOLU,,14
VATT,2,,2
VSEL,ALL
ESIZE,,2 ! Mesh density parameter
LESIZE,68,,,1,,1 ! Spring width (quarter model)
LESIZE,77,,,10,,1 ! Spring length
LESIZE,67,,,5,,1 ! Length center part
LESIZE,82,,,2,,1 ! Anchor post
LESIZE,51,,,5,,1
LESIZE,62,,,2,,1
! Y-direction
LESIZE,87,,,2,,1 ! Anchor post
LESIZE,75,,,1,,1 ! Center part
LESIZE,42,,,1,,1 ! Mirror center
LESIZE,54,,,3,,1 ! Mirror outside part
VMESH,1,12
TYPE,2
MAT,2
SMRTSIZ,2
MSHAPE,1,3D
MSHKEY,0
ESIZE,,1
VMESH,14
ALLSEL
VSYM,x,all
VSYM,y,all
NUMMRG,node,1e-5
NUMMRG,kp,1e-3
VSEL,s,type,,1
ASEL,s,ext
ASEL,u,loc,x,sp_la/2
ASEL,u,loc,x,-sp_la/2
ASEL,u,loc,z,fe_di
ASEL,u,loc,z,-d_ele
NSLA,S,1
CM,COND1A,AREA ! Mirror electrode
CM,COND1,NODE
ALLSEL
ASEL,s,area,,11
ASEL,a,area,,128
NSLA,S,1
CM,COND2A,AREA ! First fixed electrode
CM,COND2,NODE
ALLSEL
ASEL,s,area,,202
ASEL,a,area,,264
NSLA,S,1
CM,COND3A,AREA ! Second fixed electrode
CM,COND3,NODE
ALLSEL
VSEL,s,type,,2
CM,AIR,VOLU ! Region to be morphed
VSEL,ALL
ESEL,S,MAT,,1 ! Define neutral plane
NSLE,S,1 ! component
NSEL,R,LOC,Z,fe_di/2
CM,NEUN,NODE
ALLSEL
ET,1,0
PHYSICS,WRITE,ELEC ! Write electrostatic physics file
PHYSICS,CLEAR
ET,1,SOLID185,,3
ET,2,0
MP,EX,1,169e3 ! Material properties of Si
MP,NUXY,1,0.066
MP,DENS,1,2.329e-15
VSEL,s,type,,1
ASLV,s,1
ASEL,r,loc,z,-d_ele
NSLA,S,1
CM,FIXA,AREA ! Boundary condition must be
DA,ALL,UX ! applied on solid model entities
DA,ALL,UY ! Fixed boundary condition
DA,ALL,UZ
ASLV,S,1
ASEL,R,LOC,X,sp_la/2 ! Symmetry boundary conditions
DA,ALL,UX
NSLA,S,1
ASLV,S,1
ASEL,R,LOC,X,-sp_la/2
DA,ALL,UX
NSLA,A,1
CM,SYMBC,NODE
ALLSEL
PHYSICS,WRITE,STRU ! Write structural physics file
ET,2,SOLID122 ! Plot the entire model
EPLOT
FINI
SAVE ! Save model database
Generation Pass:
The following Generation Pass considers the first two of three modes: torsion mode, transversal mode in Z-direction and one mode responsible for plate warp. In addition to the capacitances between movable and fixed conductors CAP12 and CAP13, you should activate CAP23, which affects the mirror behavior in case of high polarization voltages. The total deflection range is 75% of the electrode gap.
A test load computes an approximate deflection state of the mirror for use in selecting the above modes. The test load contains two uniform pressure loads equivalent to the electrostatic pressure at the initial position.
Element loads are acceleration of 9.81 m/s2 in Z-direction and a uniform 1 MPa pressure load acting on the upper mirror wing
/filname,gener ! Specify jobname for Generation Pass
rmanl,mirror,db,,3,z ! Assign model database, dimensionality, oper. direction
resu,mirror,db ! Resume model database
! Apply element loads
physics,clear
physics,read,STRU ! Read structural physics file
/view,1,,-1
/pbc,all,1
/solu
antype,static
nlgeom,off
acel,,,9.81e6 ! Acceleration in z-direction
lswrite,1
acel,0,0,0
esel,s,type,,1
nsle,s,1
nsel,r,loc,z,0
nsel,r,loc,y,0,sp_br/2 ! Uniform pressure load on the
sf,all,pres,1 ! upper mirror wing
allsel
lswrite,2
lssolve,1,2
fini
/post1 ! Extract neutral plane displacements
set,1 ! due to the element load
rmndisp,'eload','write'
set,2
rmndisp,'eload','append'
fini
! Apply test load
physics,clear
physics,read,STRU
u_test=150 ! Voltage applied on COND1
u_pol=400 ! Polarization voltage applied on COND2 and COND3
/solu
pres1=8.85e-6*(u_pol-u_test)**2/(2*d_ele**2)
pres2=8.85e-6*(u_pol+u_test)**2/(2*d_ele**2)
esel,s,type,,1
nsle,s,1
nsel,r,loc,z,0
nsel,r,loc,y,mi_br/2,sp_br/2 ! Uniform pressure load on the
sf,all,pres,-pres1 ! upper mirror wing
allsel
esel,s,type,,1
nsle,s,1
nsel,r,loc,z,0
nsel,r,loc,y,-sp_br/2,-mi_br/2 ! Uniform pressure load on the
sf,all,pres,-pres2 ! lower mirror wing
allsel
solve
fini
/post1 ! Extract neutral plane displacements
set,last ! due to the test load
rmndisp,'tload'
fini
rmcap,cap12,1,2
rmcap,cap13,1,3
rmcap,cap23,2,3
mn1=node(0.0000,125.00,7.5000) ! Define master nodes
mn2=node(0.0000,0.0000,7.5000)
mn3=node(169.00,-104.29,0.0000)
rmaster,mn1 ! Upper node on center line
rmaster,mn2 ! Middle node on center line
rmaster,mn3 ! Lower node on center line
rmalist
physics,clear
physics,read,STRU
!
/solu ! Perform modal analysis
antype,modal
modopt,lanb,6
mxpand,6
solve
fini
/post1 ! Extract modal displacements at
rmnevec ! neutral plane nodes
fini
! Automated mode selection
rmmselect,3,'tmod',-15,15
! List selected mode parameter
rmmlist
! Edit mode parameters
rmmrange,1,'DOMINANT',,,6,0.05 ! use 6 steps for mode 1
rmmrange,3,'DOMINANT',,,5,0.05 ! use 5 steps for mode 3
rmmrange,5,'UNUSED' ! do not use mode 5
rmsave,mirror,rom ! Save ROM database
! Generate samples points and run FE analyses
rmsmple ! to calculate strain energy and capacitances
rmporder,4,,3 ! Define polynomial orders for response surface
rmroption,sene,lagrange,0
rmroption,cap12,lagrange,1
rmroption,cap13,lagrange,1
rmroption,cap23,lagrange,1
rmrgenerate ! Generate Response Surface
rmrstatus,sene ! Print status of response surface
rmrstatus,cap12
rmrstatus,cap13
rmrstatus,cap23
rmsave,mirror,rom
rmlvscale,2,0,0 ! Dummy element load factor in order to consider
! element loads for ROM export to VHDL-AMS
rmxport ! Export ROM model to external simulators
The response surfaces are fitted with Lagrange polynomials whereby the capacitance functions are inverted. Polynomial orders are four and three, which requires 20 polynomial coefficients for each response surface. A further reduction is possible. The result file gen_130.dec contains all FE sample data and gen_130.pcs the polynomial information.
Calculation of voltage displacement functions up to pull-in
! *** Voltage displacement function up to pull in
! *** A voltage sweep is applied in COND2
/clear
/filnam,use1
rmresu,mirror,rom ! Resume ROM database
/PREP7
ET,1,144,1 ! Define ROM element type
*do,i,1,30 ! Define 30 nodes
n,i
*enddo
rmuse,on ! Activate ROM use pass
e,1,2,3,4,5,6,7,8 ! Define node connectivity
emore,9,10,11,12,13,14,15,16
emore,17,18,19,20,21,22,23,24
emore,25,26,27,28,29,30
FINISH
/gst,off
! Compute voltage sweep up to pull-in,
! Sweep conductor is COND2
! Start an equidistant voltage sweep up to 800 V by a voltage increment of 10 V
! Increase voltage beyond 800 up to pull-in with accuracy of 1 Volt
! Create gap elements to converge at pull-in
DCVSWP,'pi',1,2,800,10,1
DCVSWP,'gv',1,2,859,10,,1
/post26
/axlab,x,Voltage
/axlab,y,Modal amplitudes
nsol,2,1,emf,,mode1 ! Torsion mode
nsol,3,2,emf,,mode3 ! Transversal mode
nsol,4,12,volt,,voltage ! Applied voltage
xvar,4
plvar,2,3 ! Modal displacements
/axlab,y,Nodal displacements
nsol,6,21,ux,,up_edge ! Node on the upper edge
nsol,7,22,ux,,center_n ! Node at plate center
nsol,8,23,ux,,lo_edge ! Node at the lower edge
plvar,6,7,8
finiThe computed pull-in voltage is 859 volts.
The modal amplitude and master displacements as functions of voltage are shown in Figure 8.12: Modal Amplitudes vs. Voltage and Figure 8.13: Master Displacements vs. Voltage.
Calculation of voltage displacement functions at multiple load steps
! *** Calculate voltage displacement functions at multiple load steps ! *** A voltage sweep is applied to COND1 ! *** COND2 and COND3 carry a fixed polarization voltage /clear /filname,use2 rmresu,mirror,rom /PREP7 ET,1,144 *do,i,1,20 n,i *enddo rmuse,on e,1,2,3,4,5,6,7,8 emore,9,10,11,12,13,14,15,16 emore,17,18,19,20 FINISH /gst,off /solu antyp,static outres,all,all cnvtol,curt,1.0d-6,,2 *do,i,1,45 d,11,volt,(i-1)*5-110 ! Sweep voltage at cond1 d,12,volt,800 ! Fixed polarization voltage d,13,volt,-800 ! Fixed polarization voltage lswrite,i *enddo lssolve,1,45 fini /post26 /axlab,x,Voltage /axlab,y,Modal amplitude nsol,2,1,emf,,mode1 ! Torsion mode nsol,3,2,emf,,mode3 ! Transversal mode nsol,4,11,volt,,voltage ! Applied voltage esol,5,1,,nmisc,2,cap12 esol,6,1,,nmisc,3,cap13 esol,7,1,,nmisc,4,cap23 xvar,4 plvar,2 ! Modal displacements plvar,3 /axlab,x,Voltage /axlab,y,Capacitance xvar,4 plvar,5,6 ! Capacitances plvar,7 fini
High polarization voltages of opposite sign (±800V) are applied on both fixed electrodes. The varying driving voltage is applied on the entire mirror structure. A positive voltage tilts the mirror to the right and a negative voltage to the left. The voltage stroke function of mode 1 is strongly linearized in the operating range between -60 and 60 Volt (Figure 8.14: Modal Amplitude of Mode 1 vs. High Polarization Voltage). The voltage stroke function of the transversal mode is shown in Figure 8.15: Modal Amplitude of Mode 3 vs. High Polarization Voltage. Both negative and positive voltages increase the transversal amplitude.
Calculated capacitances are shown in the following figures.
Calculation of displacements at acting element loads
! *** Calculate deflection state at acting element loads /clear /filnam,use3 rmresu,mirror,rom /PREP7 ET,1,144,1 *do,i,1,30 n,i *enddo rmuse,on e,1,2,3,4,5,6,7,8 emore,9,10,11,12,13,14,15,16 emore,17,18,19,20,21,22,23,24 emore,25,26,27,28,29,30 FINISH /gst,off /solu antyp,static outres,all,all cnvtol,curt,1.0d-6,,2 d,11,volt,0 d,12,volt,0 d,13,volt,0 outres,all,all rmlvscale,2,1,0 ! Acceleration of 9.81 m/s**2 solve rmlvscale,2,0,-0.01 ! Pressure load of 10 kPa solve fini /post1 set,1 prdisp set,2 prdisp fini ! Start expansion pass /clear /filnam,gener ! Generation Pass jobname resu,mirror,db rmre,mirror,rom physics,clear physics,read,STRU /solu rmuse,on,use3 ! Specify reduced solution file name expass,on expsol,,,,ON solve fini /post1 set,1 plnsol,u,z,2 set,2 plnsol,u,z,2 fini
An acceleration of 9.81 m/s2 and a uniform pressure load of 10 kPa were applied to the upper mirror wing. Computed displacements at the expansion pass are shown in Figure 8.18: Expanded Displacements for Acceleration Load and Figure 8.19: Expanded Displacements for Pressure Load.
Prestressed harmonic analysis
The following example demonstrates the change of harmonic transfer functions at different polarization voltages. The higher the applied polarization voltage, the more the resonance peak shifts to the left.
! *** Prestressed harmonic analysis /clear /filname,use4 rmresu,mirror,rom /PREP7 ET,1,144,1 *do,i,1,30 n,i *enddo rmuse,on e,1,2,3,4,5,6,7,8 emore,9,10,11,12,13,14,15,16 emore,17,18,19,20,21,22,23,24 emore,25,26,27,28,29,30 FINISH /gst,off /solu antyp,static outres,all,all cnvtol,curt,1.0d-6,,2 pstress,on d,11,volt,0 d,12,volt,800 d,13,volt,-800 solve fini /solu antype,harmonic pstress,on harfrq,0,5e4 nsubst,100 kbc,1 d,11,volt,1 d,12,volt,0 d,13,volt,0 solve fini /post26 /axlab,x,Frequency /axlab,y,Modal Amplitude nsol,2,1,emf,,mode1 plvar,2 /axlab,y,Nodal amplitude nsol,3,21,ux,,up_edge nsol,4,23,ux,,lo_edge plvar,3,4 /axlab,y,Phase angle plcplx,1 plvar,3,4 fini
Nonlinear Transient Analysis
! *** Nonlinear transient analysis
/clear
/filnam,use5
rmresu,mirror,rom
/PREP7
ET,1,144
*do,i,1,20
n,i
*enddo
rmuse,on
e,1,2,3,4,5,6,7,8
emore,9,10,11,12,13,14,15,16
emore,17,18,19,20
FINISH
/gst,off
/solu
cycle_t=500e-6 ! Cycle time of one saw tooth
! about 20 times the cycle time of mode 1
rise_t=cycle_t/10 ! Rise time
num_cyc=3 ! Number of cycles
antype,transient
nropt,full
deltime,rise_t/10,rise_t/10,rise_t/10
auto,off
outres,all,all
kbc,0
j=1
*do,i,1,num_cyc
time,cycle_t*(i-0.5)+rise_t*(i-1)
d,11,volt,100
d,12,volt,400
d,13,volt,-400
lswrite,j
j=j+1
time,cycle_t*(i-0.5)+rise_t*i
d,11,volt,-100
d,12,volt,400
d,13,volt,-400
lswrite,j
j=j+1
*enddo
time,cycle_t*num_cyc+rise_t*num_cyc
d,11,volt,0
lswrite,j
lssolve,1,j
fini
/post26
/axlab,y, Modal amplitudes
nsol,2,1,emf,,mode1
nsol,3,2,emf,,mode2
plvar,2,3
fini
This example demonstrates the response of a saw tooth like voltage function. The voltage displacement relationship is linearized since a high polarization voltage of 400 V is applied to both fixed electrodes. The amount of remaining oscillations depend strongly on the cycle time and the damping ratios. In practice, most mirror cells operate in a closed loop to a controller circuit to obtain better performance.