VMR038-2A 182 Input Listing


/COM,ANSYS MEDIA REL. 182 (07/10/2017) REF. VERIF. MANUAL: REL. 182
/VERIFY,vmr038-2a-182
/TITLE,vmr038-2a-182,J INTEGRAL VALUE FOR CENTERED CRACK PLATE WITH BISO MATERIAL
/COM, REFERENCE:" E.M.REMZI, NAFEMS, TWO DIMENSIONAL TEST CASES IN POST YIELD
/COM,             FRACTURE MECHANICS, REF: R0038
/COM,             CHAPTER 2.1 FROM REFERENCE ARTICLE
/COM,
/OUT,SCRATCH
/PREP7
A=25					! CRACK LENGTH
B=100					! WIDTH OF THE PLATE
H=200					! HEIGHT OF THE PLATE

ET,1,PLANE182
KEYOPT,1,3,2			! PLANE STRAIN

MP,EX,1,205000
MP,NUXY,1,0.3

TB,BISO,1,,
TBDATA,1,1000,2450		! YIELD STRESS = 1000, TANGENT MODULUS = 2450

K,1,0,0,0
K,2,25,0,0
K,3,100,0,0
K,4,100,25,0
K,5,100,200,0
K,6,0,200,0
K,7,0,25,0

A,1,2,3,4,7
A,7,4,5,6

ESIZE,4.0
KSCON,2,2.5,1,8		      ! WITH SINGULAR CRACK TIP ELEMENTS
AMESH,1
ESIZE,B/10
AMESH,2
ALLSEL,ALL

NSEL,S,LOC,Y,0
NSEL,R,LOC,X,25,100
D,ALL,UY,0				! SYMMETRIC BOUNDARY CONDITION
ALLSEL,ALL

NSEL,S,LOC,X,0
D,ALL,UX,0				! SYMMETRIC BOUNDARY CONDITION
ALLSEL,ALL
FINI

/SOLU
ANTYPE,STATIC
OUTRES,CINT,ALL
CNVTOL,F,1,0.01			! FORCE CONVERGENCE TOLERANCE
CNVTOL,U,1,0.01			! DISPLACEMENT CONVERGENCE TOLERANCE
NLGEOM,ON				! NON-LINEAR ANALYSIS
NSUBS,30,1000,30
TIME,1.0
NSEL,S,LOC,Y,200
D,ALL,UY,2				! DISPLACEMENT CONTROL
NSEL,ALL
NSEL,S,LOC,Y,0
NSEL,R,LOC,X,25,25
CM,CRACK1,NODE			! CRACK TIP NODE COMPONENT
ALLSEL,ALL
CINT,NEW,1
CINT,NAME,CRACK1
CINT,NCON,6				! NUMBER OF COUNTOURS
CINT,SYMM,OFF			! SYMMETRY TURNED OFF
CINT,NORM,0,2
ALLSEL,ALL
SOLVE
FINI

/POST1
SET,LAST
PRCINT,1
*GET,J1,CINT,1,CTIP,2,,1,,
*GET,J2,CINT,1,CTIP,2,,2,,
*GET,J3,CINT,1,CTIP,2,,3,,
*GET,J4,CINT,1,CTIP,2,,4,,
*GET,J5,CINT,1,CTIP,2,,5,,
*GET,J6,CINT,1,CTIP,2,,6,,
JC1 = (ABS(J1)+ABS(J2)+ABS(J3)+ABS(J4)+ABS(J5)+ABS(J6))/6
*STAT,JC1
*DIM,LABEL,CHAR,1
*DIM,VALUE,,1,3
LABEL(1,1) = 'JVALUE'
*VFILL,VALUE(1,1),DATA,1462
*VFILL,VALUE(1,2),DATA,JC1
*VFILL,VALUE(1,3),DATA,ABS(JC1/1462)
/OUT,vmr038-2a-182,vrt
/COM,
/COM,------------------- vmr038-2a-182 RESULTS COMPARISON --------------
/COM,
/COM,           |  TARGET  |   Mechanical APDL  |  RATIO
/COM,
/COM, 
*VWRITE,LABEL(1,1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,'   ',F10.4,'  ',F15.4,'   ',F12.3)
/COM,------------------------------------------------------------------------
/OUT,
FINISH
*LIST,vmr038-2a-182,vrt


Release 18.2 - © ANSYS, Inc. All rights reserved.