VMR038-2g 182 Input Listing


/COM,ANSYS MEDIA REL. 182 (07/10/2017) REF. VERIF. MANUAL: REL. 182
/VERIFY,vmr038-2g-182
/TITLE,vmr038-2g-182,CENTERED CRACK PLATE UNDER THERMAL LOADING WITH ELASTIC-PERFECTLY PLASTIC MATERIAL
/COM, REFERENCE : E.M.REMZI, NAFEMS, TWO DIMENSIONAL TEST CASES IN POST YIELD FRACTURE 
/COM,             MECHANICS, REF: R00038
/COM,             CHAPTER 2.7 FROM REFERENCE ARTICLE
/COM,
/PREP7
A=25					! CRACK LENGTH
B=100					! WIDTH OF THE PLATE
H=200					! HEIGHT OF THE PLATE
AF=1E-4                                 ! COEFFICIENT OF THERMAL EXPANISON 
ET,1,PLANE182				! PLANE 182 ELEMENT
KEYOPT,1,1,1
KEYOPT,1,3,2	         		! PLANE STRAIN

MP,EX,1,205000
MP,NUXY,1,0.3
MP,ALPX,1,AF                            ! THERMAL MATERIAL PROPERTIES
MP,REFT,1,0                             ! REFERENCE TEMPERATURE
TB,BISO,1,,
TBDATA,1,1000,0

K,1,0,0,0
K,2,25,0,0
K,3,100,0,0
K,4,100,25,0
K,5,100,200,0
K,6,0,200,0
K,7,0,25,0

A,1,2,3,4,7
A,7,4,5,6

ESIZE,2.5
KSCON,2,2.5,1,8,,			! SINGULAR CRACK TIP ELEMENTS
AMESH,1
ESIZE,8
AMESH,2
ALLSEL,ALL

NSEL,S,LOC,X,25,100
NSEL,R,LOC,Y,0
D,ALL,UY,0
ALLSEL

NSEL,S,LOC,X,0
D,ALL,UX,0
ALLSEL

FINI

/SOLU
ANTYPE,STATIC
OUTRES,CINT,ALL
CNVTOL,F,1,0.01
CNVTOL,U,1,0.01
NLGEOM,ON
NSUBS,20,1000,10
TIME,1

*GET,NN,NODE,0,COUNT
*DO,I,1,NN
  TT=0.01*NX(I)*NX(I) 
  BF,I,TEMP,TT                 ! THERMAL LOADING
*ENDDO
ALLSEL

NSEL,S,LOC,Y,0
NSEL,R,LOC,X,25,25
CM,CRACK1,NODE			! CRACK TIP NODE COMPONENT
ALLSEL,ALL

CINT,NEW,1
CINT,NAME,CRACK1
CINT,NCON,4			! NUMBER OF COUNTOURS AROUND CRACK TIP
CINT,SYMM,OFF			! SYMMETRY TURNED OFF
CINT,NORM,0,2
ALLSEL,ALL
SOLVE
FINI

/OUT,SCRATCH
/POST1
SET,LAST
PRCINT,1
*GET,J1,CINT,1,CTIP,2,,1,,
*GET,J2,CINT,1,CTIP,2,,2,,
*GET,J3,CINT,1,CTIP,2,,3,,
*GET,J4,CINT,1,CTIP,2,,4,,
JC1 = (ABS(J2)+ABS(J3)+ABS(J4))/3
*STAT,JC1
*DIM,LABEL,CHAR,1
*DIM,VALUE,,1,3
LABEL(1,1) = 'J-VALUE'
*VFILL,VALUE(1,1),DATA,105.8
*VFILL,VALUE(1,2),DATA,JC1
*VFILL,VALUE(1,3),DATA,ABS(JC1/105.8)
/OUT,vmr038-2g-182,vrt
/COM, -----------------vmr038-2g-182 RESULTS COMPARISON -----------------
/COM,
/COM,           |  TARGET  |   Mechanical APDL  |  RATIO
/COM,
/COM, PLAIN STRAIN WITH LOAD CONTROL
/COM, --------------------------------
/COM,
*VWRITE,LABEL(1,1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,'   ',F10.4,'  ',F14.4,'   ',F15.3)
/COM,
/COM,
/COM,------------------------------------------------------------------------
/OUT,
FINISH
*LIST,vmr038-2g-182,vrt


Release 18.2 - © ANSYS, Inc. All rights reserved.