VMR038-3A 183 Input Listing


/COM,ANSYS MEDIA REL. 182 (07/10/2017) REF. VERIF. MANUAL: REL. 182
/VERIFY,vmr038-3a-183
/TITLE,vmr038-3a-183,J INTEGRAL FOR COMPACT TENSION SPECIMEN WITH BISO MATERIAL
/COM, REFERENCE: E.M.REMZI,NAFEMS,TWO DIMENSIONAL TEST CASES IN POST YIELD 
/COM,            FRACTURE MECHANICS,R00038
/COM,            CHAPTER 3.1 FROM REFERENCE ARTICLE
/COM,
/OUT,SCRATCH
/PREP7
A = 29.78					! CRACK LENGTH
L = 50					! LENGTH OF THE PLATE
W = 30					! WIDTH OF THE PLATE
B = 20.112

ET,1,PLANE183				! PLANE 183 ELEMENT
KEYOPT,1,3,2				! PLANE STRAIN

MP,EX,1,205000
MP,NUXY,1,0.3

TB,BISO,1
TBDATA,1,550,3044

K,1,0,0,0
K,2,29.78,0,0
K,3,50,0,0
K,4,50,15,0
K,5,50,30,0
K,6,0,30,0
K,7,0,20.112,0
K,8,0,15,0

A,1,2,3,4,5,6,7,8

KSCON,2,0.75,1,5,,
ESIZE,4
AMESH,1
ALLSEL,ALL

NSEL,S,LOC,X,29.78,50
NSEL,R,LOC,Y,0
D,ALL,UY,0
NSEL,ALL

NSEL,S,LOC,X,50
NSEL,R,LOC,Y,0
D,ALL,UX,0
ALLSEL,ALL

KSEL,S,,,7
NSLK,S
D,ALL,UY,1.05
NSEL,ALL
FINI

/SOLU
ANTYPE,STATIC
OUTRES,CINT,ALL
CNVTOL,F,1,0.001
CNVTOL,U,1,0.001
NLGEOM,ON
NSUBS,10,1000,10
TIME,1.0

NSEL,S,LOC,X,29.78,29.78
NSEL,R,LOC,Y,0
CM,CRACK1,NODE
ALLSEL,ALL


CINT,NEW,1
CINT,NAME,CRACK1
CINT,NCON,4
CINT,SYMM,OFF
CINT,NORM,0,2
ALLSEL,ALL
SOLVE
FINI

/POST1
SET,LAST
N1=NODE(0,20.112,0)
*GET,RFORCE,NODE,N1,RF,FY
ALLSEL,ALL
/COM,
/COM, TOTAL REACTION FORCE AT POINT P IS 64970 N (FROM REFERENCE)
/COM, REACTION FORCE AT POINT P IS TOTAL LOAD/THICKNESS = 64970/25.2 = 2578 N
/COM, 
PRCINT,1
*GET,J1,CINT,1,CTIP,2,,1,,
*GET,J2,CINT,1,CTIP,2,,2,,
*GET,J3,CINT,1,CTIP,2,,3,,
*GET,J4,CINT,1,CTIP,2,,4,,
JC1 = (ABS(J1)+ABS(J2)+ABS(J3)+ABS(J4))/4
*STAT,JC1
*DIM,LABEL,CHAR,1,2
*DIM,VALUE,,2,3
LABEL(1,1) = 'J1'
LABEL(1,2) = 'RF@P'
*VFILL,VALUE(1,1),DATA,230.8
*VFILL,VALUE(1,2),DATA,JC1
*VFILL,VALUE(1,3),DATA,ABS(JC1/230.8)
*VFILL,VALUE(2,1),DATA,2578
*VFILL,VALUE(2,2),DATA,RFORCE
*VFILL,VALUE(2,3),DATA,RFORCE/2578
/OUT,vmr038-3a-183,vrt
/COM,------------------- vmr038-3a-183 RESULTS COMPARISON --------------
/COM,
/COM,           |  TARGET  |   Mechanical APDL  |  RATIO
/COM,
/COM, 
/COM, AVERAGE J INTEGRAL VALUE
/COM,
*VWRITE,LABEL(1,1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,'   ',F10.4,'  ',F14.4,'   ',F15.3)
/COM,
/COM, REACTION FORCE AT POINT P
/COM,
*VWRITE,LABEL(1,2),VALUE(2,1),VALUE(2,2),VALUE(2,3)
(1X,A8,'   ',F10.4,'  ',F14.4,'   ',F15.3)
/COM,----------------------------------------------------------------------
/OUT,
FINISH
*LIST,vmr038-3a-183,vrt


Release 18.2 - © ANSYS, Inc. All rights reserved.