VMR038-4A 183 Input Listing


/COM,ANSYS MEDIA REL. 182 (07/10/2017) REF. VERIF. MANUAL: REL. 182
/VERIFY,vmr038-4a-183
/TITLE,vmr038-4a-183,J INTEGRAL FOR 3 PT BEND SPECIMEN WITH POWER LAW HARDENING MATERIAL
/COM, REFERENCE: E.M.REMZI, NAFEMS, TWO DIMENSIONAL TEST CASES IN POST YIELD FRACTURE
/COM,            MECHANICS, REF: R00038
/COM,		     CHAPTER 4.1 FROM REFERENCE ARTICLE
/COM,
/OUT,SCRATCH
/PREP7
ET,1,PLANE183
KEYOPT,1,3,2			! PLANE STRAIN

A = 12.7				! CRACK LENGTH
W = 25.4				! WIDTH OF THE PLATE
L = 50.8				! LENGTH OF THE PLATE

K,1,0,0,0
K,2,12.7,0,0
K,3,25.4,0,0
K,4,25.4,15,0
K,5,25.4,50.8,0
K,6,0,50.8,0
K,7,0,15,0
K,8,10,50.8,0
K,9,10,40.8,0
K,10,0,40.8,0

A,1,2,3,4,7
A,7,4,5,8,9,10
A,10,9,8,6


MP,EX,1,214800
MP,NUXY,1,0.3

TB,NLISO,1,,,POWER
TBDATA,1,275,0.1

KSCON,2,0.75,1,8,,
ESIZE,1.25
AMESH,1

ESIZE,6
AMESH,2
ALLSEL,ALL

ESIZE,5				! REFINING THE MESH NEAR LOADING AREA
AMESH,3
ALLSEL,ALL

NUMMRG,NODE
NUMMRG,KP
ALLSEL,ALL

NSEL,S,LOC,X,12.7,25.4
NSEL,R,LOC,Y,0
D,ALL,UY,0
NSEL,ALL

NSEL,S,LOC,X,25.4,25.4
NSEL,R,LOC,Y,0
D,ALL,UX,0
NSEL,ALL

NSEL,S,LOC,X,0
NSEL,R,LOC,Y,50.8
D,ALL,UX,2				! APPLIED DISPLACEMENTS
NSEL,ALL
ALLSEL,ALL
FINI

/SOLU
ANTYPE,STATIC
OUTRES,CINT,ALL
NLGEOM,ON
NSUBS,10,1000,10
CNVTOL,F,1,0.001			! FORCE CONVERGENCE
CNVTOL,U,1,0.001			! DISPLACEMENT CONVERGENCE
TIME,1
NSEL,S,LOC,X,12.7,12.7
NSEL,R,LOC,Y,0
CM,CRACK1,NODE
ALLSEL,ALL
CINT,NEW,1
CINT,CTNC,CRACK1
CINT,NCON,10
CINT,SYMM,ON
CINT,NORM,0,2
ALLSEL,ALL
SOLVE
FINI


/POST1
SET,LAST
PRCINT,1
*GET,J1,CINT,1,CTIP,2,,1,,
*GET,J2,CINT,1,CTIP,2,,2,,
*GET,J3,CINT,1,CTIP,2,,3,,
*GET,J4,CINT,1,CTIP,2,,4,,
*GET,J5,CINT,1,CTIP,2,,5,,
*GET,J6,CINT,1,CTIP,2,,6,,
*GET,J7,CINT,1,CTIP,2,,7,,
*GET,J8,CINT,1,CTIP,2,,8,,
*GET,J9,CINT,1,CTIP,2,,9,,
*GET,J10,CINT,1,CTIP,2,,10,,
JC1 = (ABS(J1)+ABS(J2)+ABS(J3)+ABS(J4)+ABS(J5)+ABS(J6)+ABS(J7)+ABS(J8)+ABS(J9)+ABS(J10))/10
*STAT,JC1
*DIM,LABEL,CHAR,1
*DIM,VALUE,,1,3
LABEL(1,1) = 'J-VALUE '
*VFILL,VALUE(1,1),DATA,203.8
*VFILL,VALUE(1,2),DATA,JC1
*VFILL,VALUE(1,3),DATA,ABS(JC1/203.8)
/OUT,vmr038-4a-183,vrt
/COM,
/COM, --------------------vmr038-4a-183 RESULTS COMPARISON------------
/COM,
/COM,           |  TARGET  |   Mechanical APDL  |  RATIO
/COM,
/COM, 
*VWRITE,LABEL(1,1),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,'   ',F10.4,'  ',F14.4,'   ',F15.3)
/COM,--------------------------------------------------------------------- 
/OUT,
FINISH
*LIST,vmr038-4a-183,vrt


Release 18.2 - © ANSYS, Inc. All rights reserved.